Atténuation des bombardements de messagerie

Un bombardement d’e-mails est un type d’attaque en ligne dans lequel l’attaquant envoie une quantité massive d’e-mails à une adresse ou un réseau informatique spécifique afin de saturer la boite de réception du destinataire.

Une forme de plus en plus courante de cette attaque consiste à bombarder la messagerie de l’utilisateur avec des e-mails de confirmation d’inscription.

Proton Mail propose un filtrage des indésirables pour empêcher les messages indésirables d’atteindre votre boîte de réception. Cependant, dans le cas des bombardements d’e-mails, l’activité de spam tend à provenir de formulaires d’inscription légitimes, ce qui peut dans certains cas rendre le filtre anti-indésirables inefficace. Dans ces situations, vous pouvez utiliser un filtre Sieve plus avancé. Cet article explique les étapes pour ajouter un filtre Sieve à votre boîte de réception.

IMPORTANT : en appliquant les filtres Sieve ci-dessous, il existe un risque de faux positifs qui filtreront également les messages légitimes. Pour cette raison, nous vous recommandons de ne le garder actif que pendant la durée de l’attaque.

Comment atténuer un bombardement d’e-mails avec un filtre Sieve

Connectez-vous à votre compte sur la version web de Proton Mail à l’adresse mail.proton.me et suivez ces étapes :

1. Créez un label qui sera appliqué à tous les e-mails identifiés comme faisant partie de l’attaque par bombardement de messagerie.

• Allez dans Paramètres -> Dossiers/Labels.
• Cliquez sur « AJOUTER UN LABEL », créez un label appelé « Mail bomb » et cliquez sur « Enregistrer ».

2. Créez un filtre Sieve qui va soit abandonner tous les messages, soit envoyer tous les messages vers votre dossier Spam.

• Allez dans Paramètres -> Filtres et cliquez sur « AJOUTER UN FILTRE SIEVE ».
• Dans le champ « Nom », créez un nom pour votre filtre Sieve.
• Dans le champ « Script Sieve », copiez et collez l’une des options de code ci-dessous.

Il existe quatre options de filtre Sieve que vous pouvez utiliser, selon les caractéristiques des e-mails que vous recevez et ce que vous souhaitez faire des e-mails capturés par le filtre :

1. Un filtre qui abandonne les messages en fonction du contenu de l’en-tête contenant certains mots-clés courants. Lorsque ce filtre est appliqué, les messages filtrés n’atteindront jamais la boîte de réception, c’est pourquoi nous suggérons d’appliquer les filtres Sieve uniquement pour la durée de l’attaque :

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Une variante un peu plus douce de la première option. Plutôt que d’abandonner les messages, ce filtre les déplace vers votre dossier Spam et applique le label « Mail bomb » :

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Un filtre qui déplace les formulaires d’inscription et/ou d’abonnement entrants vers les spams et applique le label « Mail bomb » :

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Un filtre qui déplace tous les messages de newsletter vers votre dossier Spam et applique le label « Mail bomb ». Ce filtre correspondra également aux e-mails provenant du domaine « mypapertoday.com ».

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Pour les messages déplacés vers les spams, vous pouvez facilement les examiner plus tard (en recherchant le label « Mail bomb ») pour vous assurer que des messages n’ont pas été capturés par erreur par le filtre. Le label utilisé pour ce filtre peut être facilement modifié en remplaçant simplement le mot « Mail bomb » dans les étapes 2 à 4 ci-dessus par celui de votre choix.

Veuillez noter que les abonnements gratuits ont des limites quant au nombre de filtres et de labels pouvant être utilisés.

Enfin, vous pouvez lire notre article sur la façon d’éviter le spam pour en savoir plus sur la manière de prévenir ce type d’attaques à l’avenir.