Mitigação de bombardeio de e-mails

Uma bomba de e-mail é um tipo de ataque on-line no qual o invasor envia uma quantidade massiva de e-mails para um endereço ou rede de computadores específica com o objetivo de sobrecarregar a caixa de entrada do destinatário.

Uma forma cada vez mais comum desse ataque consiste em bombardear a caixa de correio do usuário com e-mails de confirmação de cadastro.

O Proton Mail oferece filtragem de spam para evitar que mensagens de spam cheguem à sua caixa de entrada. No entanto, no caso de bombas de e-mail, a atividade de spam tende a vir de formulários de cadastro legítimos, o que pode, em alguns casos, tornar o filtro de spam ineficaz. Para essas situações, você pode usar um filtro Sieve mais avançado. Este artigo explicará as etapas para adicionar um filtro Sieve à sua caixa de entrada.

IMPORTANTE: Ao aplicar os filtros Sieve abaixo, há o risco de falsos positivos que também filtrarão mensagens legítimas. Por esse motivo, recomendamos mantê-los ativos apenas durante o ataque.

Como mitigar uma bomba de e-mail com um filtro Sieve

Acesse sua conta na versão web do Proton Mail em mail.proton.me e siga estas etapas:

1. Crie um marcador que será aplicado a todos os e-mails identificados como parte do ataque de bomba de e-mail.

• Vá em Configurações -> Pastas/Marcadores.
• Clique em “ADICIONAR MARCADOR”, crie um marcador chamado “Mail bomb” e clique em “Salvar”.

2. Crie um filtro Sieve que descartará todas as mensagens ou enviará todas as mensagens para a sua pasta de Spam.

• Vá em Configurações -> Filtros e clique em “ADICIONAR FILTRO SIEVE”.
• No campo “Nome”, crie um nome para o seu filtro Sieve.
• No campo “Script Sieve”, copie e cole uma das opções de código abaixo.

Existem quatro opções de filtro Sieve que você pode usar, dependendo das características dos e-mails que está recebendo e do que deseja fazer com os e-mails capturados pelo filtro:

1. Um filtro que descarta as mensagens com base no conteúdo do cabeçalho que contém certas palavras-chave comuns. Quando esse filtro é aplicado, as mensagens filtradas nunca chegarão à Caixa de entrada, razão pela qual sugerimos aplicar os filtros Sieve apenas durante o ataque:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Uma variante um pouco mais suave da primeira opção. Em vez de descartar as mensagens, este filtro as move para a sua pasta de Spam e aplica o marcador “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Um filtro que move formulários de cadastro e/ou assinatura recebidos para o Spam e aplica o marcador “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Um filtro que move todas as mensagens de boletins informativos para a sua pasta de Spam e aplica o marcador “Mail bomb”. Este filtro também corresponderá a e-mails do domínio “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Para mensagens movidas para o Spam, você pode revisá-las facilmente mais tarde (pesquisando pelo marcador “Mail bomb”) para garantir que as mensagens não tenham sido capturadas pelo filtro por engano. O marcador usado para este filtro pode ser facilmente alterado simplesmente substituindo a palavra “Mail Bomb” nas etapas de 2 a 4 acima pelo que você preferir.

Observe que os planos gratuitos têm limitações na quantidade de filtros e marcadores que podem ser usados.

Finalmente, você pode ler nosso artigo sobre como evitar spam para saber mais sobre como prevenir tipos semelhantes de ataques no futuro.