Mitigazione delle email bomb

Un’email bomb è un tipo di attacco online in cui l’attaccante invia una quantità massiccia di email a un indirizzo o a una rete di computer specifici al fine di intasare la posta in arrivo del destinatario.

Una forma sempre più comune di questo attacco consiste nel bombardare la casella email dell’utente con email di conferma dell’iscrizione.

Proton Mail offre un filtro spam per evitare che i messaggi di spam raggiungano la posta in arrivo. Tuttavia, nel caso delle email bomb, l’attività di spamming tende a provenire da moduli di iscrizione legittimi, il che in alcuni casi potrebbe rendere inefficace il filtro spam. Per queste situazioni, puoi utilizzare un filtro Sieve più avanzato. Questo articolo ti spiegherà i passaggi per aggiungere un filtro Sieve alla tua posta in arrivo.

IMPORTANTE: applicando i filtri Sieve qui sotto, c’è il rischio di falsi positivi che filtreranno anche messaggi legittimi. Per questo motivo, ti consigliamo di tenerli attivi solo per la durata dell’attacco.

Come mitigare un’email bomb con un filtro Sieve

Accedi al tuo account sulla versione web di Proton Mail su mail.proton.me e segui questi passaggi:

1. Crea un’etichetta che verrà applicata a tutte le email identificate come parte dell’attacco mail bomb.

• Vai su Impostazioni -> Cartelle/Etichette.
• Fai clic su “AGGIUNGI ETICHETTA”, crea un’etichetta chiamata “Mail bomb” e fai clic su “Salva”.

2. Crea un filtro Sieve che rimuoverà tutti i messaggi o invierà tutti i messaggi alla tua cartella Spam.

• Vai su Impostazioni -> Filtri e fai clic su “AGGIUNGI FILTRO SIEVE”.
• Nel campo “Nome”, crea un nome per il tuo filtro Sieve.
• Nel campo “Script Sieve”, copia e incolla una delle opzioni di codice riportate di seguito.

Ci sono quattro opzioni di filtri Sieve che puoi utilizzare, a seconda delle caratteristiche delle email che ricevi e di cosa desideri fare con le email intercettate dal filtro:

1. Un filtro che rimuove i messaggi in base al contenuto dell’intestazione che contiene determinate parole chiave comuni. Quando questo filtro viene applicato, i messaggi filtrati non raggiungeranno mai la Posta in arrivo, motivo per cui consigliamo di applicare i filtri Sieve solo per la durata dell’attacco:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Una variante leggermente più blanda della prima opzione. Invece di rimuovere i messaggi, questo filtro li sposta nella tua cartella Spam e applica l’etichetta “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Un filtro che sposta i moduli di registrazione e/o abbonamento in arrivo in Spam e applica l’etichetta “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Un filtro che sposta tutti i messaggi delle newsletter nella tua cartella Spam e applica l’etichetta “Mail bomb”. Questo filtro corrisponderà anche alle email provenienti dal dominio “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Per i messaggi spostati in Spam, puoi facilmente esaminarli in un secondo momento (cercando l’etichetta “Mail bomb”) per assicurarti che non siano stati intercettati dal filtro per errore. L’etichetta utilizzata per questo filtro può essere facilmente modificata semplicemente sostituendo la parola “Mail bomb” nei passaggi da 2 a 4 sopra indicati con quella che preferisci.

Tieni presente che i piani gratuiti presentano limitazioni sul numero di filtri ed etichette che è possibile utilizzare.

Infine, puoi leggere il nostro articolo su come evitare lo spam per scoprire di più su come prevenire tipi di attacchi simili in futuro.